W D Gann's Stock vibrations and market structure

{Cmacdon Note: Click on heading or the indicator on chart and black vertical line appears which you should drag across the chart to the bar before the turning point you wish to start from}

[Target=Price;]

TDate:=InputDate("Date of trend", date(2014,7,10));
HD:=BarsSince(OnOrSkipped(TDate));

pd:=input("Period", 2, 1, 10);

HLd:=If(CLOSE>Ref(Ma(H,pd,S),-1),
{then}1,
{else}If(CLOSE<Ref(Ma(L,pd,S),-1),
{then}-1,
{else}0));
HLv:=ValueWhen(1,HLd<>0,HLd);
HiLo:=If(HLv=-1,
{then}Ma(H,pd,S),
{else}Ma(L,pd,S));
HiLo;

[name=Fill; linestyle=fill;]
[color=Lime; ]
if(HD,C,undefined);

[color=Red; ]
if(HD,HiLo,undefined);

HiLoTrend:=if(HiLo>=Hist(HiLo,1),1,if(HiLo<Hist(HiLo,1),-1,prev));

[drawundefined=gap]

[Linestyle=Solid; Width=2;]
[name=HiLo; Color=Blue]
pl1a:=if(HD AND HiLoTrend=1 and hist(HiLoTrend,1)=-1,HiLo,if(HD AND HiLoTrend=-1,HiLo,undefined));
pl1a;

[Color=Red]
pl2a:=if(HD AND HiLoTrend=-1 ,HiLo,if(HD AND hist(HiLoTrend,1)=1,HiLo,undefined));
pl2a;

[Color=Lime]
pl3a:=if(HD AND HiLoTrend=1 or HiLoTrend=0,HiLo,undefined);
pl3a;

[linestyle=pricecolor]

[color=Lime Green] if(hd and H>=HiLO,1, undefined);

[color=Dark Violet] if(hd and L<HiLo,1,undefined);

[color=Black] true;

Note after the next bar the indicator redraws the last 6 to 8 congested bars and identifies the final trough and change to an uptrend mode but it came after the actual event.



Edited by cmacdon - 26 Aug 2014 at 6:50pm

In this version 14.08% version (otherwise same as above) I extended the Hold level period from 100 to 1000

{Cmacdon note: Step I- Work out what is the market structure definition your are happy to work with. }

[Description="Cmacdon For this example, I adapted a different indicator, to use as the market structure engine and applied it to W D Gann's Bull and Bear campaign DJIA analysis see previous case study posts"]

[target=price; Visible=True]

[target=Price]
Vib:=input("Vibration", 4, .001, 100);
z:=Zig(If(Outside() AND Ref(H,-1)>Ref(H,-2),H,If(Outside() AND Ref(L,-1)<Ref(L,-2),L,If((Outside() OR Inside()) AND C>O,H,If((Outside() OR Inside()) AND O>C,L,If(H>Ref(H,-1),H,If(L<Ref(L,-1),L,If(Ref(H,-1)>Ref(H,-2),H,If(Ref(L,-1)<Ref(L,-2),L,C)))))))),Vib,%);
ispeak := z>hist(z,1) and z>future(z,1);
istrough := z<hist(z,1) and z<future(z,1);

[linestyle=Solid; color=Red]
z;

Upfractal:=If(ispeak, H*1.001,undefined);
Downfractal:=If(istrough{L<ref(L,1) and L<ref(L,-1)}, L*0.999,undefined);

{Text for interpreting market structure showing positive Blue structure Higher Highs(HH)and higher lows (ll), and negative structure, Lower Lows (LL), and lower highs (lh)}

[name=HH; linestyle=Text;fontsize=8; textalign=Above,Centre; color=Blue;]
if(Upfractal>Valuewhen(2,Upfractal,upfractal), + "HH ", +"");
Upfractal*1.001;

[name=lh; linestyle=Text;fontsize=8; textalign=Above,Centre; color=Red;]
if(Upfractal>Valuewhen(2,Upfractal,upfractal), + "", +"lh");
Upfractal*1.001;

[name=LL; linestyle=Text;fontsize=8; textalign=BELOW,Center; color=Red;]
if(Downfractal<Valuewhen(2,Downfractal,Downfractal), + "LL ", +"");
Downfractal*0.999;

[name=hl; linestyle=Text;fontsize=8; textalign=BELOW,Center; color=Blue;]
if(Downfractal<Valuewhen(2,Downfractal,Downfractal), + "", +"hl");
Downfractal*0.999;

{----------This draws Lines I called Creek and Ice (Wyckoff terms)for want of names-------}

HoldLevelPeriod :=
Input("Hold Level Period",100,1);

FrU:=ValueWhen(1,UpFractal,UpFractal);
FrUb:=If(H < FrU and barssince(UpFractal)<HoldLevelPeriod, FrU, undefined);

[name=Creek; linestyle=Horz Step; color=blue; width=1]
FrUb;

FrD:=ValueWhen(1,DownFractal,DownFractal);
FrDb:=If(L > FrD and barssince(DownFractal)<HoldLevelPeriod,FrD,undefined);

[Name=Ice; linestyle=Horz Step; color=red; width=1]
FrDb;

{-----------------------------Colour Market Structure--------------------------------------}

Switch:=if(barssince(valuewhen(1,upfractal))<barssince(valuewhen(1,downfractal)),Frub,Frdb);

{ Fill }
[name=Market Structure Fill; linestyle=fill;]

[color=Red] If((L>valuewhen(1,FRUb)),H,Switch);

[color=Cyan] C;

[linestyle=pricecolor]

[color=Green] If( c>=valuewhen(1,FRU) OR switch =FRD and c>valuewhen(1,FRD),1,undefined);

[color=Red] If( c<=valuewhen(1,FRD) OR Switch = FRU and c<valuewhen(1,FRU) ,1,undefined);

[color=Black] ;


[Visible=True]

jck:=Cross(C,Valuewhen(2,FRU));
[name=JCk; linestyle=marker; marker=Long;align=Above; ]
jck;

bki:=Cross(Valuewhen(2,FRD),C);
[name=BkIce; linestyle=marker; marker=short; align=Below;]
bki;




Edited by cmacdon - 23 Aug 2014 at 8:42am